define wiring in separate file

[challenge-bot] / 3d-printables / sonar-table-top-holder-data.scad

/*
  Copyright (C) 2015 Daniel Watson
  See the end of the file for license conditions.
*/
// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available here:
// https://challenge-bot.com/

/*
  this holds an hc-sr04 sonar sensor to a 3/16 inch deck.
  http://fritzing.org/projects/hc-sr04-project
  it can hold the sonar sensor either facing down, or forwards.
  when facing down, it can detect if it passes over the edge of a table.
  when facing forwards, it can detect and follow something in front of it.
 */

$fn = 60;

// 3/16 inch in mm deck_depth = 4.7625;
// 1/4 inch in mm = 6.35
// subtract a little to be a squeeze fit
deck_depth = 4.7625 - 0.4;
// sonar sensor measurements taken with calipers:
//  10.82 in between, 42.33 outside, 15.82 diameter
// measured diameter of 15.82 with calipers,
//  but when printed ends up being too small, so add some
sonar_diameter = 15.82 + 0.5;
sonar_radius = sonar_diameter / 2;
sonar_height = 13.8;
between_sonar_centers = sonar_diameter + 10.82;
// the sonar cylinders are placed on the pcb at slightly different positions
//  from one sensor to the next, so this allows for that variance.
between_sonar_centers_variance = 2;
// keep at least this much plastic surrounding the sonar cylinder on all sides
buffer = 3;
sonar_holder_length = buffer + between_sonar_centers + sonar_diameter + buffer;
sonar_holder_width = buffer + sonar_diameter + buffer;
// sonar_holder_depth is deck_depth minus a little bit to make arm fit
//  into deck holder
sonar_holder_depth = deck_depth - 0.7875;

deck_holder_length = sonar_holder_depth * 2 + deck_depth + 15;
module sonar_holder_2d() {
  difference() {
    square([sonar_holder_length, sonar_holder_width]); } }

module sonars() {
  translate([between_sonar_centers / 2, 0, 0]) {
    hull() {
      cylinder(r = sonar_radius, h = sonar_height);
      // for the variance with which the physical sonar cylinders are placed
      translate([ -between_sonar_centers_variance, 0, 0]) {
        cylinder(r = sonar_radius, h = sonar_height); } } }
  translate([-between_sonar_centers / 2, 0, 0]) {
    cylinder(r = sonar_radius, h = sonar_height); } }

module sonar_holder() {
  elbow_length = deck_depth - 0.2;
  rounded_corner_radius = buffer;
  difference() {
    cube([sonar_holder_length, sonar_holder_width, sonar_holder_depth]);
    translate([sonar_holder_length / 2, sonar_holder_width / 2, -0.05]) {
      sonars(); }
    translate([sonar_holder_length,
               sonar_holder_width,
               0]) {
      corner_rounder(rounded_corner_radius,
                     sonar_holder_depth,
                     "bottom-right"); } }
  translate([sonar_holder_length, 0, 0]) {
    cube([elbow_length, deck_depth, sonar_holder_depth]);
    translate([elbow_length, 0, 0]) {
      linear_extrude(height = sonar_holder_depth) {
        polygon([[                 0, 0],
                 [sonar_holder_depth, 0],
                 [sonar_holder_depth, sonar_holder_width / 2],
                 [                 0, sonar_holder_width / 2
                                      + sonar_holder_depth]]); }
      translate([0, (sonar_holder_width + sonar_holder_depth) / 2, 0]) {
        cube([sonar_holder_depth / 2,
              (sonar_holder_width - sonar_holder_depth) / 2 + 0.8,
              sonar_holder_depth]); }
      translate([-1.7, sonar_holder_width + 0.8, 0]) {
        linear_extrude(height = sonar_holder_depth) {
          polygon([[                           0, 0],
                   [sonar_holder_depth / 2 + 1.7, 4],
                   [sonar_holder_depth / 2 + 1.7, 0]]); } } } } }

module corner_rounder_2d(radius, corner_name = "top-left") {
  rotate_for_corner = (corner_name == "top-left") ? 0 :
                      ((corner_name == "top-right") ? -90 :
                       ((corner_name == "bottom-left") ? 90 :
                        ((corner_name == "bottom-right") ? 180 :
                         1 / 0)));
  rotate(rotate_for_corner) {
    difference() {
      square(radius);
      translate([radius, radius]) {
        circle(radius); } } } }

module corner_rounder(radius, height, corner_name = "top-left") {
  linear_extrude(height = height) {
    corner_rounder_2d(radius, corner_name); } }

/*
  This file is part of challenge-bot.

  Challenge-bot is free software: you can redistribute it and/or modify
  it under the terms of the GNU Affero General Public License as published by
  the Free Software Foundation, either version 3 of the License, or
  (at your option) any later version.

  GNU Affero Emacs is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  GNU Affero General Public License for more details.

  You should have received a copy of the GNU Affero General Public License
  along with challenge-bot.  If not, see <http://www.gnu.org/licenses/>.
*/