// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available at these locations:
// https://gitorious.org/ozzloy/challenge-bot
// https://github.com/waynegramlich/challenge-bot

/*
  this holds an hc-sr04 sonar sensor to a 3/16 inch deck.
  http://fritzing.org/projects/hc-sr04-project
  it can hold the sonar sensor either facing down, or forwards.
  when facing down, it can detect if it passes over the edge of a table.
  when facing forwards, it can detect and follow something in front of it.
 */

$fn = 60;

use <oshw.scad>
// 3/16 inch in mm deck_depth = 4.7625;
// 1/4 inch in mm = 6.35
// subtract a little to be a squeeze fit
deck_depth = 4.7625 - 0.4;
// sonar sensor measurements taken with calipers:
//  10.82 in between, 42.33 outside, 15.82 diameter
// measured diameter of 15.82 with calipers,
//  but when printed ends up being too small, so add some
sonar_diameter = 15.82 + 0.4;
sonar_radius = sonar_diameter / 2;
sonar_height = 13.8;
between_sonar_centers = sonar_diameter + 10.82;
// the sonar cylinders are placed on the pcb at slightly different positions
//  from one sensor to the next, so this allows for that variance.
between_sonar_centers_variance = 2;
// keep at least this much plastic surrounding the sonar cylinder on all sides
buffer = 3;
sonar_holder_length = buffer + between_sonar_centers + sonar_diameter + buffer;
sonar_holder_width = buffer + sonar_diameter + buffer;
// sonar_holder_depth is deck_depth minus a little bit to make arm fit
//  into deck holder
sonar_holder_depth = deck_depth - 0.7875;

deck_holder_length = sonar_holder_depth * 2 + deck_depth + 15;

oshw_dy = 120.366;
oshw_dx = 133.888;

// 3/16 inch in mm deck_depth = 4.7625;
// 1/4 inch in mm = 6.35
// subtract a little to be a squeeze fit
deck_depth = 4.7625 - 0.4;
// sonar sensor measurements taken with calipers:
//  10.82 in between, 42.33 outside, 15.82 diameter
// measured diameter of 15.82 with calipers,
//  but when printed ends up being too small, so add some
sonar_diameter = 15.82 + 0.4;
sonar_radius = sonar_diameter / 2;
sonar_height = 13.8;
between_sonar_centers = sonar_diameter + 10.82;
// the sonar cylinders are placed on the pcb at slightly different positions
//  from one sensor to the next, so this allows for that variance.
between_sonar_centers_variance = 2;
// keep at least this much plastic surrounding the sonar cylinder on all sides
buffer = 3;
sonar_holder_length = buffer + between_sonar_centers + sonar_diameter + buffer;
sonar_holder_width = buffer + sonar_diameter + buffer;
// sonar_holder_depth is deck_depth minus a little bit to make arm fit
//  into deck holder
sonar_holder_depth = deck_depth - 0.7875;

deck_holder_length = sonar_holder_depth * 2 + deck_depth + 15;

module sonars() {
  translate([between_sonar_centers / 2, 0, 0]) {
    cylinder(r = sonar_radius, h = sonar_height); }
  // for the variance with which the physical sonar cylinders are placed
  translate([between_sonar_centers / 2 - between_sonar_centers_variance, 0, 0]) {
    cylinder(r = sonar_radius, h = sonar_height);
    translate([0, -sonar_radius, 0]) {
      cube([between_sonar_centers_variance, sonar_diameter, sonar_height]); } }
  translate([-between_sonar_centers / 2, 0, 0]) {
    cylinder(r = sonar_radius, h = sonar_height); } }

module sonar_holder() {
  elbow_length = deck_depth;
  rounded_corner_radius = buffer;
  difference() {
    cube([sonar_holder_length, sonar_holder_width, sonar_holder_depth]);
    translate([sonar_holder_length / 2, sonar_holder_width / 2, -0.05]) {
      sonars(); }
    translate([sonar_holder_length - rounded_corner_radius,
               sonar_holder_width - rounded_corner_radius,
               0]) {
      corner_rounder(rounded_corner_radius, sonar_holder_depth); } }
  translate([sonar_holder_length, 0, 0]) {
    cube([elbow_length, deck_depth, sonar_holder_depth]);
    translate([elbow_length, 0, 0]) {
      linear_extrude(height = sonar_holder_depth) {
        polygon([[                 0, 0],
                 [sonar_holder_depth, 0],
                 [sonar_holder_depth, sonar_holder_width / 2],
                 [                 0,
                                   sonar_holder_width / 2 + sonar_holder_depth]]); }
      translate([0, (sonar_holder_width + sonar_holder_depth) / 2, 0]) {
        cube([sonar_holder_depth / 2,
              (sonar_holder_width - sonar_holder_depth) / 2 + 0.8,
              sonar_holder_depth]); }
      translate([-1.7, sonar_holder_width + 0.8, 0]) {
        linear_extrude(height = sonar_holder_depth) {
          polygon([[                           0, 0],
                   [sonar_holder_depth / 2 + 1.7, 4],
                   [sonar_holder_depth / 2 + 1.7, 0]]); } } } } }

module deck_holder() {
  deck_holder_width = sonar_holder_width - deck_depth;
  deck_holder_height = sonar_holder_depth * 2 + deck_depth;
  linear_extrude(height = deck_holder_width) {
    difference() {
      square([deck_holder_length, deck_holder_height]);
      translate([sonar_holder_depth - 0.15, sonar_holder_depth - 0.15]) {
        square(deck_depth + 0.3); }
      translate([deck_holder_height, sonar_holder_depth - 0.3]) {
        square([deck_holder_length - (deck_holder_height),
                deck_depth + 0.6]); } } }
  translate([deck_holder_length - oshw_dy * 0.05, 0, deck_holder_width / 2])
  scale([0.1, 1, 0.1])
  rotate(v = [1, 0, 0], a = 90)
  rotate(90)
  linear_extrude(height = 0.5)
  oshw();
  translate([deck_holder_length - oshw_dy * 0.05,
             deck_holder_height + 0.5,
             deck_holder_width / 2])
  rotate(v = [1, 0, 0], a = 90)
  rotate(90)
  scale([0.1, 0.1, 1])
  linear_extrude(height = 0.5)
  oshw(); }

module corner_rounder_2d(radius) {
  difference() {
    square(radius);
    circle(radius); } }

module corner_rounder(radius, height) {
  linear_extrude(height = height) {
    corner_rounder_2d(radius); } }