/*
  Copyright (C) 2015 Daniel Watson
  See the end of the file for license conditions.
*/
// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available here:
// https://challenge-bot.com/

// from schematic http://goo.gl/96RKol
collar_radius = 9.2 / 2 + 0.75;
nubbin_radius = 4.48 / 2 + 0.5;
screw_radius = 2.9 / 2 + 0.8; // a little bigger so screws fit through

motor_height = 22.23;

// http://freespace.virgin.net/matt.waite/resource/handy/screwsize.htm
_6_radius = 3.5 / 2 + 0.75;

// measurements we made up:
mount_total_x = 38;
mount_total_y = mount_total_x;
mount_total_z = 3.175; // 3/16 in mm

module motor_holes() {
  collar_x_offset = 10.8;
  nubbin_x_offset = 22.23;
  // actual motor screw holes are 0.2 further than spec says
  screw_x_offset = 30.81 + 0.2;
  screw_y_offset = 17.44 / 2;

  translate([collar_x_offset, 0, 0]) {
    cylinder(r = collar_radius, h = mount_total_z + 0.1); }
  translate([nubbin_x_offset, 0, 0]) {
    cylinder(r = nubbin_radius, h = mount_total_z + 0.1); }
  translate([screw_x_offset, 0, 0]) {
    translate([0, screw_y_offset, 0]) {
      cylinder(r = screw_radius, h = mount_total_z + 0.1); }
    translate([0, -screw_y_offset, 0]) {
      cylinder(r = screw_radius, h = mount_total_z + 0.1); } } }

module bracket_holes() {
  translate([6.2, 0, 0]) {
    cylinder(r = _6_radius, h = mount_total_z + 0.1); }
  translate([mount_total_x - 6.2, 0, 0]) {
    cylinder(r = _6_radius, h = mount_total_z + 0.1); } }

module motor_mount() {
  difference() {
    cube([mount_total_x, mount_total_y, mount_total_z]);
    translate([0, 6.2, -0.05]) {
      bracket_holes(); }
    translate([1, mount_total_y - motor_height / 2 - 3, -0.05]) {
      motor_holes(); } } }

/*
  This file is part of challenge-bot.

  Challenge-bot is free software: you can redistribute it and/or modify
  it under the terms of the GNU Affero General Public License as published by
  the Free Software Foundation, either version 3 of the License, or
  (at your option) any later version.

  GNU Affero Emacs is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  GNU Affero General Public License for more details.

  You should have received a copy of the GNU Affero General Public License
  along with challenge-bot.  If not, see <http://www.gnu.org/licenses/>.
*/