// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available at these locations:
// https://gitorious.org/ozzloy/challenge-bot
// https://github.com/waynegramlich/challenge-bot

standoff_height = 55; // eyeballed
nut_short_side = 4.7; // from calipers
nut_height = 1.6; // from calipers
standoff_radius = 14.732 / 2; // 0.580 / 2 inches from spec sheet
screw_radius = 2.286/2;  // 0.090 inches
caster_flange_screw_length = 8; // eyeballed
// eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
caster_flange_height = 2.9464 * 2;
caster_flange_width = 20.32;  // 0.800 inches
ziptie_width = 4.7625; // 3/16 inch
ziptie_height = 3; // i'm guessing

module caster_flange_screws(){
  translate([standoff_radius, 0, 0])
    cylinder(h = caster_flange_screw_length, r = screw_radius, $fn = 20);
  translate([-standoff_radius, 0, 0])
    cylinder(h = caster_flange_screw_length, r = screw_radius, $fn = 20);}

module caster_flange(){
  side_radius = caster_flange_width / 2 - standoff_radius;
  hull(){
    cylinder(h = caster_flange_height, r = standoff_radius);
    translate([standoff_radius, 0, 0])
      cylinder(h = caster_flange_height, r = side_radius);
    translate([-standoff_radius, 0, 0])
      cylinder(h = caster_flange_height, r = side_radius);}}

module nut(size, height){
    width = size/1.75;
    for (r = [-60, 0, 60]) rotate([0,0,r]) cube([width, size, height], true);}

module nuts(){
  translate([standoff_radius, 0, nut_height/2])
    nut(nut_short_side, nut_height);
  translate([-standoff_radius, 0, nut_height/2])
    nut(nut_short_side, nut_height);}

module caster_standoff(){
  difference(){
    union(){
      cylinder(h = standoff_height, r = standoff_radius);
      translate([0, 0, standoff_height - caster_flange_height])
        caster_flange();}
    translate([0, 0, standoff_height - caster_flange_screw_length * 1.1 + 0.1])
      scale([1, 1, 1.1])
        caster_flange_screws();
    translate([0, 0, standoff_height - (caster_flange_height + nut_height)])
      nuts();}}

caster_standoff();