// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available at these locations:
// https://gitorious.org/ozzloy/challenge-bot
// https://github.com/waynegramlich/challenge-bot

$fn = 60;

// 3/16 inch in mm deck_depth = 4.7625;
// 1/4 inch in mm - a little to be a squeeze fit
deck_depth = 6.35 - 0.4;
sonar_plate_width = 20;
// sonar sensor measurements taken with calipers:
//  10.82 in between, 42.33 outside, 15.82 diameter
// measured diameter of 15.82 with calipers,
//  but when printed ends up being too small
sonar_sensor_radius = 15.82 / 2 + 0.3;
sonar_sensor_height = 13.8;
between_sensor_centers = 15.82 + 10.82;
sonar_plate_length = 3 + between_sensor_centers + sonar_sensor_radius + 3;
sonar_holder_length = sonar_plate_length + 10;
sonar_holder_width = sonar_plate_width + 3;
sonar_holder_depth = 4;

deck_holder_length = 30;
deck_holder_width = sonar_holder_width;

module sensors(){
  translate([between_sensor_centers / 2, 0, 0]){
    cylinder(r = sonar_sensor_radius, h = sonar_sensor_height);}
  translate([-between_sensor_centers / 2, 0, 0]){
    cylinder(r = sonar_sensor_radius, h = sonar_sensor_height);}}

module sensor_holder(){
  difference(){
    cube([sonar_holder_length, sonar_holder_width, sonar_holder_depth]);
    translate([sonar_holder_length / 2, sonar_holder_width / 2, -0.05]){
      sensors();}}
  translate([sonar_holder_length, 0, 0]){
    cube([sonar_holder_depth + 0.3, deck_depth - 0.3, deck_depth - 0.3]);
    translate([sonar_holder_depth + 0.3, 0, 0]){
      // subtract a little bit (0.3) to make it fit
      cube([deck_depth - 0.3, sonar_holder_width, deck_depth - 0.3]);}}}

module deck_holder(){
  cube([deck_holder_length, sonar_holder_depth, sonar_holder_width]);
  cube([sonar_holder_depth,
        sonar_holder_depth * 2 + deck_depth,
        sonar_holder_width]);
  translate([0, sonar_holder_depth + deck_depth, 0]){
    cube([deck_holder_length, sonar_holder_depth, sonar_holder_width]);}
  translate([sonar_holder_depth + deck_depth, 0, 0]){
    cube([sonar_holder_depth,
          sonar_holder_depth * 2 + deck_depth,
          sonar_holder_width]);}}

module sonar_table_top_holder(){
  difference(){
    union(){
      cube([sonar_holder_length, sonar_holder_width, sonar_holder_depth]);
      translate([sonar_holder_length, 0, 0]){
        deck_holder();}}
    translate([between_sensor_centers / 2 + sonar_sensor_radius + 3,
               sonar_holder_width / 2,
               -1]){
      sensors();}
    // cut out a bit of the circle to make it 3d printable,
    //  no severe overhang
    translate([3 + sonar_sensor_radius,
               sonar_holder_width - 3.025,
               sonar_holder_depth / 2 - 0.025]){
      cube([10, 6.1, sonar_holder_depth + .1], center = true);
      translate([between_sensor_centers, 0, 0]){
        cube([10, 6.1, sonar_holder_depth + .1], center = true);}}}}

sensor_holder();