squish 3030 outside corner and lock in tight fitting print settings

[ozzloy@gmail.com/3d-printables] / mk2-haribo-spool-holder.scad

/* GNU AGPLv3 (or later at your option)
   see bottom for more license info */

/* measurements from misumi's 3030 aluminum extrusion data sheet
   https://us.misumi-ec.com/pdf/fa/2012/p2_0545.pdf
*/

x = 30;
y = 30;
diagonal = sqrt(pow(30/2, 2) + pow(30/2, 2));
opening_width = 8;
inner_block = 12;

outer_block = (30 - 16.5) / 2;
wall = 2;

$fn = 100;

module arm_half(){
  // inner block
  square(inner_block / 2);

  // diagonal arms connecting inner block to outer blocks
  rotate(45) {
    square([diagonal - wall, wall / 2]); }

  // outer block, without the wall part since wall has rounded corner
  translate([x / 2 - outer_block, y / 2 - outer_block]) {
    square(outer_block - wall); }

  // outer arms covering the opening
  translate([(opening_width + wall) / 2, y / 2 - wall]) {
    square([(x - opening_width - wall) / 2 - wall, wall]); }
  // rounded part at entrace to inside
  translate([(opening_width + wall) / 2, (y - wall) / 2]){
    circle(d = wall); }
  // rounded part around outside of extrusion
  corner_squish = 0.1;
  translate([x / 2 - wall + corner_squish, y / 2 - wall + corner_squish]) {
    circle(wall - corner_squish); } }

module 3030_profile(){
  arms = 4;
  for(arm = [0:arms - 1]) {
    rotate(arm * 360 / arms) {
      arm_half();
      mirror(){ arm_half(); } } } }

linear_extrude(height = 35){
  difference(){
    minkowski(){
      square(30, true);
      circle(5);}
    minkowski(){
      3030_profile();
      circle(0.2);} } }


/*
  This file is part of 3d-printables.

  3d-printables is free software: you can redistribute it and/or modify
  it under the terms of the GNU Affero General Public License as published by
  the Free Software Foundation, either version 3 of the License, or
  (at your option) any later version.

  3d-printables is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  GNU Affero General Public License for more details.

  You should have received a copy of the GNU Affero General Public License
  along with challenge-bot.  If not, see <http://www.gnu.org/licenses/>.
*/