remove unused ring module

[ozzloy@gmail.com/3d-printables] / spin-data.scad

/* GNU AGPLv3 (or later at your option)
   see bottom for more license info */

/* spin thing that erin likes */
$fn = 50;

layer_height = 0.15;

weight = "penny";
// weight = "608zz";
bearing = "608zz";
weight_lip_overhang = 0.3;
bearing_lip_overhang = weight_lip_overhang;
// TODO: switch wall_thickness -> wall
wall_thickness = 3;
wall = 3;
penny_thickness = 1.52;
penny_radius = 19.05 / 2;

_608zz_radius = 22 / 2;
_608zz_inner_radius = 8.1 / 2;
_608zz_cover_radius = 19.4 / 2;
_608zz_cap_footprint_radius = 12 / 2;
_608zz_thickness = 7;

weight_radius = (weight == "penny") ? penny_radius : _608zz_radius;
weight_thickness = (weight == "penny") ?
     penny_thickness * 5 : _608zz_thickness;

bearing_radius = (bearing == "608zz") ? _608zz_radius : 1/0;
bearing_inner_radius = (bearing == "608zz") ? _608zz_inner_radius : 1/0;
bearing_cover_radius = (bearing == "608zz")
                       ? _608zz_cover_radius + wall
                       : 1/0;
bearing_cap_footprint_radius =
     (bearing == "608zz") ? _608zz_cap_footprint_radius : 1/0;
bearing_thickness = (bearing == "608zz") ? _608zz_thickness : 1/0;

spinner_height = penny_thickness * 5 + 2;
arms = 3;

module cap(bearing_inner_radius,
           bearing_cap_footprint_radius,
           bearing_cover_radius,
           bearing_thickness) {
  footprint_height = 1.6;
  footprint_radius_safety = 0.25;
  cap_height = 3;
  bearing_cover_radius_safety = 0.75;
  bearing_thickness_safety = 0.2;

  difference() {
    union() {
      cylinder(r1 = bearing_cover_radius - tan(30) * cap_height,
               r2 = bearing_cover_radius,
               h = cap_height);
      linear_extrude(height = cap_height + footprint_height) {
        circle(bearing_cap_footprint_radius - footprint_radius_safety); }
      linear_extrude(height = cap_height
                              + footprint_height
                              + bearing_thickness / 2
                              - bearing_thickness_safety) {
        circle(bearing_inner_radius); } }
    translate([0, 0, -0.01]) {
      cylinder(r1 = bearing_inner_radius + tan(30) * (cap_height - 1),
               r2 = bearing_inner_radius,
               h = cap_height - 1); } } }

module fillet(r) {
  offset(r = -r) { offset(delta = r) { children(); } } }

module spin_footprint(weight_radius,
                      bearing_radius,
                      round_extra,
                      wall,
                      arms) {
  thinner_radius = (bearing_radius < weight_radius)?
    bearing_radius : weight_radius;
  fillet(thinner_radius) {
    for(arm = [0 : arms - 1]) {
      hull() {
        circle(bearing_radius + round_extra);
        rotate( (arm / arms) * 360 ) {
          translate([bearing_radius + wall + weight_radius, 0]) {
            circle(weight_radius + round_extra); } } } } } }

module mirrored(axis) {
  children();
  mirror(axis) children(); }

module spin(weight_radius,
            weight_thickness,
            bearing_radius,
            bearing_thickness,
            weight_lip_overhang = 0.3,
            bearing_lip_overhang = 0.3,
            wall = 3,
            arms = 3) {
  layer_height = 0.15;
  thicker_thickness = (bearing_thickness > weight_thickness) ?
    bearing_thickness : weight_thickness;
  calculated_height = thicker_thickness + 2 * wall;
  layers = 2 * ceil(ceil(calculated_height / layer_height) / 2);
  actual_height = layers * layer_height;
  round_radius = actual_height / 2;

  mirrored([0, 0, 1]) {
    for(layer = [0 : (layers / 2) - 1]) {
      translate([0, 0, layer * layer_height - actual_height / 2]) {
        linear_extrude(height = layer_height) {
          adjacent = round_radius - (layer * layer_height);
          angle = acos(adjacent / round_radius);
          round_extra = adjacent * tan(angle);
          spin_footprint(weight_radius,
                         bearing_radius,
                         round_extra,
                         wall,
                         arms); } } } } }

/*
  This file is part of 3d-printables.

  3d-printables is free software: you can redistribute it and/or modify
  it under the terms of the GNU Affero General Public License as published by
  the Free Software Foundation, either version 3 of the License, or
  (at your option) any later version.

  3d-printables is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  GNU Affero General Public License for more details.

  You should have received a copy of the GNU Affero General Public License
  along with challenge-bot.  If not, see <http://www.gnu.org/licenses/>.
*/