/* GNU AGPLv3 (or later at your option)
   see bottom for more license info */

/* measurements from misumi's 3030 aluminum extrusion data sheet
   https://us.misumi-ec.com/pdf/fa/2012/p2_0545.pdf
*/

x = 30;
y = 30;
diagonal = sqrt(pow(30/2, 2) + pow(30/2, 2));
opening_width = 8;
inner_block = 12;

major_block_corner_diameter = 4;
major_block_corner_radius = major_block_corner_diameter / 2;

corner_block_inner = (30 - 16.5) / 2;
wall = 2;

$fn = 40;

module arm_half(){
  square(inner_block / 2);
  rotate(45) {
    square([diagonal - major_block_corner_radius, wall / 2]); }
  translate([x / 2 - corner_block_inner, y / 2 - corner_block_inner]) {
    square(corner_block_inner - wall); }
  translate([(opening_width + major_block_corner_diameter) / 2,
             y/2 - wall]) {
    square([(x - opening_width - 2 * major_block_corner_diameter) / 2,
            wall]);
    translate([0, wall/2]){
      circle(wall / 2); } }
  translate([(x - major_block_corner_diameter) / 2,
             (y - major_block_corner_diameter) / 2]) {
    circle(major_block_corner_radius); } }

arms = 4;
for(arm = [0:arms - 1]) {
  rotate(arm * 360 / arms) {
    arm_half();
    mirror(){ arm_half(); } } }

/*
  This file is part of 3d-printables.

  3d-printables is free software: you can redistribute it and/or modify
  it under the terms of the GNU Affero General Public License as published by
  the Free Software Foundation, either version 3 of the License, or
  (at your option) any later version.

  3d-printables is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  GNU Affero General Public License for more details.

  You should have received a copy of the GNU Affero General Public License
  along with challenge-bot.  If not, see <http://www.gnu.org/licenses/>.
*/