| 1 | /* |
| 2 | Copyright (C) 2015 Daniel Watson |
| 3 | See the end of the file for license conditions. |
| 4 | */ |
| 5 | // challenge-bot |
| 6 | // GNU AGPLv3 (or later at your option) |
| 7 | // project available here: |
| 8 | // https://challenge-bot.com/ |
| 9 | |
| 10 | use <oshw.scad> |
| 11 | |
| 12 | // use 10 ish for development, 60 or so for printing |
| 13 | $fn = 60; |
| 14 | |
| 15 | /* measured with calipers */ |
| 16 | ball_diameter = 11 + 0.75; // extra bit added for printing imprecision |
| 17 | ball_radius = ball_diameter / 2; |
| 18 | |
| 19 | standoff_height = 60; // kyle eyeballed |
| 20 | |
| 21 | gap = 3; |
| 22 | wall_thickness = 1; |
| 23 | holder_floor = 3; |
| 24 | holder_arms_length = 20; |
| 25 | holder_height = |
| 26 | holder_floor + holder_arms_length + (11 / 16) * ball_diameter; |
| 27 | |
| 28 | holder_radius = ball_radius + wall_thickness; |
| 29 | holder_diameter = holder_radius * 2; |
| 30 | |
| 31 | standoff_radius = holder_radius; // 0.580 / 2 inches from spec sheet |
| 32 | standoff_lower_portion_height = standoff_height - holder_height; |
| 33 | |
| 34 | // eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger |
| 35 | caster_flange_height = 5; |
| 36 | caster_flange_width = 20.32; // 0.800 inches |
| 37 | |
| 38 | deck_pitch = 25.4; // measured center to center on grid on pegboard |
| 39 | deck_flange_height = 2.9464; |
| 40 | deck_flange_screw_radius = 3.556 / 2; // For #6 machine screws |
| 41 | deck_flange_radius = (deck_pitch) / 2 + deck_flange_screw_radius + 3; |
| 42 | |
| 43 | module deck_flange() { |
| 44 | deck_pitch_diagonal = sqrt(2 * pow(deck_pitch, 2)); |
| 45 | difference() { |
| 46 | scale([0.35, 0.35, 1]) { |
| 47 | linear_extrude(height = deck_flange_height) { |
| 48 | oshw(); } } |
| 49 | for (ii = [-1, 1]) { |
| 50 | translate([deck_pitch_diagonal / 2 * ii, 0, -.1]) |
| 51 | cylinder(h = deck_flange_height * 1.1, |
| 52 | r = deck_flange_screw_radius); } |
| 53 | translate([0, deck_pitch_diagonal / 2, -.1]) |
| 54 | cylinder(h = deck_flange_height * 1.1, |
| 55 | r = deck_flange_screw_radius); } } |
| 56 | |
| 57 | module deck_flange_reinforcement() { |
| 58 | translate([-deck_flange_radius, |
| 59 | -.5 * deck_flange_height / 2, |
| 60 | deck_flange_height]) { |
| 61 | difference() { |
| 62 | cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]); |
| 63 | translate([-.1, -.05 * deck_flange_height, 0]) { |
| 64 | rotate([0, -45, 0]) { |
| 65 | cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2) |
| 66 | deck_flange_height * 1.1, // 1.1 is bigger than 1 |
| 67 | deck_flange_radius]); } } } } } |
| 68 | |
| 69 | module ball_holder() { |
| 70 | difference() { |
| 71 | union() { |
| 72 | cylinder(r = holder_radius, h = holder_height); |
| 73 | translate([0, 0, holder_arms_length]) { |
| 74 | cylinder(r1 = holder_radius, |
| 75 | r2 = holder_radius + wall_thickness, |
| 76 | h = wall_thickness); |
| 77 | translate([0, 0, wall_thickness]) { |
| 78 | cylinder(r = wall_thickness + holder_radius, |
| 79 | h = holder_height |
| 80 | - holder_arms_length |
| 81 | - wall_thickness); } } } |
| 82 | translate([0, 0, ball_radius + holder_floor + holder_arms_length]) { |
| 83 | sphere(r = ball_radius); } |
| 84 | translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]) { |
| 85 | cube([holder_diameter + wall_thickness * 2 + 0.1, |
| 86 | gap, |
| 87 | holder_height - holder_floor + 0.1], |
| 88 | center = true); } } } |
| 89 | |
| 90 | module caster_standoff() { |
| 91 | cylinder(h = standoff_lower_portion_height, |
| 92 | r = standoff_radius); |
| 93 | deck_flange(); |
| 94 | for (ii = [0:3]) { |
| 95 | rotate([0, 0, 45 + 90 * ii]) |
| 96 | deck_flange_reinforcement(); } |
| 97 | translate([0, 0, standoff_lower_portion_height]) { |
| 98 | ball_holder(); } } |
| 99 | |
| 100 | /* |
| 101 | This file is part of challenge-bot. |
| 102 | |
| 103 | Challenge-bot is free software: you can redistribute it and/or modify |
| 104 | it under the terms of the GNU Affero General Public License as published by |
| 105 | the Free Software Foundation, either version 3 of the License, or |
| 106 | (at your option) any later version. |
| 107 | |
| 108 | GNU Affero Emacs is distributed in the hope that it will be useful, |
| 109 | but WITHOUT ANY WARRANTY; without even the implied warranty of |
| 110 | MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the |
| 111 | GNU Affero General Public License for more details. |
| 112 | |
| 113 | You should have received a copy of the GNU Affero General Public License |
| 114 | along with challenge-bot. If not, see <http://www.gnu.org/licenses/>. |
| 115 | */ |