ball holder holds ball, needs rolling bumpers

[challenge-bot] / 3d-printables / caster-standoff.scad

// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available at these locations:
// https://gitorious.org/ozzloy/challenge-bot
// https://github.com/waynegramlich/challenge-bot

// use 10 ish for development, 60 or so for printing
$fn = 60;

standoff_radius = 14.732 / 2; // 0.580 / 2 inches from spec sheet
standoff_height = 48; // eyeballed

// eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
caster_flange_height = 5;
caster_flange_width = 20.32;  // 0.800 inches
caster_flange_screw_radius = 2.286 / 2;  // 0.090 inches
caster_flange_screw_length = 8; // eyeballed

deck_grid_width = 25.4; // measured center to center on grid on pegboard
deck_flange_height = 2.9464;
deck_flange_screw_radius = 3.556 / 2;  // For #6 machine screws
deck_flange_radius = (deck_grid_width) / 2 + deck_flange_screw_radius + 3;

module deck_flange(){
  difference(){
    cylinder(h = deck_flange_height, r = deck_flange_radius);
    for(ii = [-1, 1]){
      translate([deck_grid_width / 2 * ii, 0, -.1])
        cylinder(h = deck_flange_height * 1.1,
                 r = deck_flange_screw_radius);
      translate([0, deck_grid_width / 2 * ii, -.1])
        cylinder(h = deck_flange_height * 1.1,
        r = deck_flange_screw_radius);}}}

module deck_flange_reinforcement(){
  translate([-deck_flange_radius,
             -.5 * deck_flange_height / 2,
             deck_flange_height]){
    difference (){
      cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]);
      translate([-.1, -.05 * deck_flange_height, 0]){
        rotate([0, -45, 0]){
          cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
                deck_flange_height * 1.1, // 1.1 is bigger than 1
                deck_flange_radius]);}}}}}

module caster_standoff(){
  cylinder(h = standoff_height - caster_flange_height,
           r = standoff_radius);
  deck_flange();
  for(ii = [0:3]){
    rotate([0, 0, 45 + 90 * ii])
      deck_flange_reinforcement();}
  caster_deck_interlock_solid();}

module ball_holder(){
  /* measured with calipers */
  ball_diameter = 12.7 + 0.5;
  ball_radius = ball_diameter / 2;

  wall_thickness = 1.5;
  holder_height = ball_radius + wall_thickness * 2;

  holder_outer_radius = ball_radius + wall_thickness;
  holder_outer_diameter = holder_outer_radius * 2;

  difference (){
    cylinder(r = holder_outer_radius, h = holder_height);
    translate([0, 0, ball_radius + wall_thickness]){
      sphere(r = ball_radius);}
    translate([0, 0, holder_height / 2 + wall_thickness]){
      cube([holder_outer_diameter + 0.1,
            wall_thickness * 2,
            holder_height],
           center = true);}}}

ball_holder();
//caster_standoff();