more closely match dobervich's actual piece

[challenge-bot] / 3d-printables / motor-mount.scad

// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available at these locations:
// https://gitorious.org/ozzloy/challenge-bot
// https://github.com/waynegramlich/challenge-bot

$fn = 60;

// from schematic http://goo.gl/96RKol
collar_radius = 9.2 / 2;
// subtract a bit to make snap fit
nubbin_radius = (4.48 - 0.3) / 2;  // make snap fit
screw_radius = 2.9 / 2 + 0.1; // a little bigger so screws fit through

motor_height = 22.23;

// http://freespace.virgin.net/matt.waite/resource/handy/screwsize.htm
_6_radius = 3.5 / 2;

// measurements we made up:
mount_total_x = 38;
mount_total_y = mount_total_x;
mount_total_z = 3.175; // 3/16 in mm

module motor_holes(){
  collar_x_offset = 10.8;
  nubbin_x_offset = 22.23;
  // actual motor screw holes are 0.2 further than spec says
  screw_x_offset = 30.81 + 0.2;
  screw_y_offset = 17.44 / 2;

  translate([collar_x_offset, 0, 0]){
    cylinder(r = collar_radius, h = mount_total_z + 0.1);}
  translate([nubbin_x_offset, 0, 0]){
    cylinder(r = nubbin_radius, h = mount_total_z + 0.1);}
  translate([screw_x_offset, 0, 0]){
    translate([0, screw_y_offset, 0]){
      cylinder(r = screw_radius, h = mount_total_z + 0.1);}
    translate([0, -screw_y_offset, 0]){
      cylinder(r = screw_radius, h = mount_total_z + 0.1);}}}

module bracket_holes(){
  translate([6.2, 0, 0])
    cylinder(r = _6_radius, h = mount_total_z + 0.1);
  translate([mount_total_x - 6.2, 0, 0])
    cylinder(r = _6_radius, h = mount_total_z + 0.1);}

module motor_mount(){
  difference(){
    cube([mount_total_x, mount_total_y, mount_total_z]);
    translate([0, 6.2, -0.05]){
      bracket_holes();}
    translate([1, mount_total_y - motor_height / 2 - 3, -0.05]){
      motor_holes();}}}

motor_mount();