switch to linear extrude for arm of sonar holder

[challenge-bot] / 3d-printables / sonar-table-top-holder.scad

// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available at these locations:
// https://gitorious.org/ozzloy/challenge-bot
// https://github.com/waynegramlich/challenge-bot

$fn = 60;

// 3/16 inch in mm deck_depth = 4.7625;
// 1/4 inch in mm = 6.35
// subtract a little to be a squeeze fit
deck_depth = 4.7625 - 0.4;
sonar_plate_width = 20;
// sonar sensor measurements taken with calipers:
//  10.82 in between, 42.33 outside, 15.82 diameter
// measured diameter of 15.82 with calipers,
//  but when printed ends up being too small
sonar_sensor_radius = 15.82 / 2 + 0.3;
sonar_sensor_height = 13.8;
between_sensor_centers = sonar_sensor_radius * 2 + 10.82;
between_sensor_centers_variance = 2;
buffer = 3;
sonar_plate_length =
  buffer + between_sensor_centers + sonar_sensor_radius + buffer;
sonar_holder_length = sonar_plate_length + 10;
sonar_holder_width = sonar_plate_width + 3;
// sonar_holder_depth is deck_depth minus a little bit to make arm fit
//  into deck holder
sonar_holder_depth = deck_depth - 0.8;

deck_holder_length = sonar_holder_depth * 2 + deck_depth + 15;

module sensors(){
  translate([between_sensor_centers / 2, 0, 0]){
    cylinder(r = sonar_sensor_radius, h = sonar_sensor_height);}
  translate([between_sensor_centers / 2 - between_sensor_centers_variance,
             0,
             0]){
    cylinder(r = sonar_sensor_radius, h = sonar_sensor_height);
    translate([0, -sonar_sensor_radius, 0]){
      cube([between_sensor_centers_variance,
            sonar_sensor_radius * 2,
            sonar_sensor_height]);}}
  translate([-between_sensor_centers / 2, 0, 0]){
    cylinder(r = sonar_sensor_radius, h = sonar_sensor_height);}}

module sensor_holder(){
  arm_depth = sonar_holder_depth;
  elbow_length = deck_depth + 0.8;
  difference(){
    cube([sonar_holder_length, sonar_holder_width, sonar_holder_depth]);
    translate([sonar_holder_length / 2, sonar_holder_width / 2, -0.05]){
      sensors();}}
  translate([sonar_holder_length - 1, 0, 0]){
    cube([elbow_length + arm_depth + 1, deck_depth, arm_depth]);
    translate([elbow_length + 1, 0, 0]){
      linear_extrude(height = arm_depth){
        polygon([[0, 0],
                 [arm_depth, 0],
                 [arm_depth, sonar_holder_width / 2],
                 [0, sonar_holder_width / 2 + arm_depth]]);}
      translate([0, (sonar_holder_width + arm_depth) / 2, 0]){
        cube([arm_depth / 2,
              (sonar_holder_width - arm_depth) / 2 + 0.8,
              arm_depth]);}
      translate([-1.7, sonar_holder_width + 0.8, 0]){
        linear_extrude(height = arm_depth){
          polygon([[0, 0],
                   [arm_depth / 2 + 1.7, 4],
                   [arm_depth / 2 + 1.7, 0]]);}}}}}

module deck_holder(){
  deck_holder_width = sonar_holder_width - deck_depth;
  linear_extrude(height = deck_holder_width){
    difference(){
      square([deck_holder_length, sonar_holder_depth * 2 + deck_depth]);
      translate([sonar_holder_depth, sonar_holder_depth]){
        square(deck_depth);}
      translate([sonar_holder_depth * 2 + deck_depth, sonar_holder_depth]){
        square([deck_holder_length - (sonar_holder_depth * 2 + deck_depth),
                deck_depth]);}}}}

translate([0, sonar_holder_depth * 2 + deck_depth + 2, 0]){
  sensor_holder();}
deck_holder();