| 1 | // challenge-bot |
| 2 | // GNU AGPLv3 (or later at your option) |
| 3 | // project available at these locations: |
| 4 | // https://gitorious.org/ozzloy/challenge-bot |
| 5 | // https://github.com/waynegramlich/challenge-bot |
| 6 | |
| 7 | standoff_radius = 14.732 / 2; // 0.580 / 2 inches from spec sheet |
| 8 | standoff_height = 55; // eyeballed |
| 9 | |
| 10 | nut_short_side = 4.7; // from calipers |
| 11 | nut_height = 1.6; // from calipers |
| 12 | |
| 13 | // eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger |
| 14 | caster_flange_height = 2.9464 * 2; |
| 15 | caster_flange_width = 20.32; // 0.800 inches |
| 16 | caster_flange_screw_radius = 2.286 / 2; // 0.090 inches |
| 17 | caster_flange_screw_length = 8; // eyeballed |
| 18 | |
| 19 | deck_grid_width = 17.4; // guessing |
| 20 | deck_flange_height = 2.9464 * 2; |
| 21 | deck_flange_screw_radius = 3.556 / 2; // For #6 machine screws |
| 22 | deck_flange_radius = deck_grid_width * 1.5; |
| 23 | |
| 24 | module deck_flange(){ |
| 25 | difference(){ |
| 26 | cylinder(h = deck_flange_height, r = deck_flange_radius); |
| 27 | for(ii = [-1, 1]){ |
| 28 | translate([deck_grid_width * ii, 0, -.1]) |
| 29 | cylinder(h = deck_flange_height * 1.1, |
| 30 | r = deck_flange_screw_radius, |
| 31 | $fn = 20);} |
| 32 | for(ii = [-1, 1]){ |
| 33 | translate([0, deck_grid_width * ii, -.1]) |
| 34 | cylinder(h = deck_flange_height * 1.1, |
| 35 | r = deck_flange_screw_radius, |
| 36 | $fn = 20);}}} |
| 37 | |
| 38 | module deck_flange_reinforcement(){ |
| 39 | translate([-deck_flange_radius, |
| 40 | -.5 * deck_flange_height, |
| 41 | deck_flange_height]){ |
| 42 | difference (){ |
| 43 | cube([deck_flange_radius, deck_flange_height, deck_flange_radius]); |
| 44 | translate([-.1, -.05 * deck_flange_height, 0]){ |
| 45 | rotate([0, -45, 0]){ |
| 46 | cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2) |
| 47 | deck_flange_height * 1.1, // 1.1 is bigger than 1 |
| 48 | deck_flange_radius]);}}}}} |
| 49 | |
| 50 | module caster_flange_screws(){ |
| 51 | translate([standoff_radius, 0, 0]) |
| 52 | cylinder(h = caster_flange_screw_length, |
| 53 | r = caster_flange_screw_radius, |
| 54 | $fn = 20); |
| 55 | translate([-standoff_radius, 0, 0]) |
| 56 | cylinder(h = caster_flange_screw_length, |
| 57 | r = caster_flange_screw_radius, |
| 58 | $fn = 20);} |
| 59 | |
| 60 | module caster_flange(){ |
| 61 | side_radius = caster_flange_width / 2 - standoff_radius; |
| 62 | hull(){ |
| 63 | cylinder(h = caster_flange_height, r = standoff_radius); |
| 64 | translate([standoff_radius, 0, 0]) |
| 65 | cylinder(h = caster_flange_height, r = side_radius); |
| 66 | translate([-standoff_radius, 0, 0]) |
| 67 | cylinder(h = caster_flange_height, r = side_radius);}} |
| 68 | |
| 69 | module nut(size, height){ |
| 70 | width = size/1.75; |
| 71 | for (r = [-60, 0, 60]) rotate([0,0,r]) cube([width, size, height], true);} |
| 72 | |
| 73 | module nuts(){ |
| 74 | translate([standoff_radius, 0, nut_height/2]) |
| 75 | nut(nut_short_side, nut_height); |
| 76 | translate([-standoff_radius, 0, nut_height/2]) |
| 77 | nut(nut_short_side, nut_height);} |
| 78 | |
| 79 | module caster_standoff(){ |
| 80 | difference(){ |
| 81 | union(){ |
| 82 | cylinder(h = standoff_height, r = standoff_radius); |
| 83 | translate([0, 0, standoff_height - caster_flange_height]) |
| 84 | caster_flange();} |
| 85 | translate([0, 0, standoff_height - caster_flange_screw_length * 1.1 + 0.1]) |
| 86 | scale([1, 1, 1.1]) |
| 87 | caster_flange_screws(); |
| 88 | translate([0, 0, standoff_height - (caster_flange_height + nut_height)]) |
| 89 | nuts();} |
| 90 | deck_flange(); |
| 91 | for(ii = [0:3]){ |
| 92 | rotate([0, 0, 45 + 90 * ii]) |
| 93 | deck_flange_reinforcement();}} |
| 94 | |
| 95 | caster_standoff(); |