--- /dev/null
+// challenge-bot
+// GNU AGPLv3 (or later at your option)
+// project available at these locations:
+// https://gitorious.org/ozzloy/challenge-bot
+// https://github.com/waynegramlich/challenge-bot
+
+use <oshw.scad>
+
+// use 10 ish for development, 60 or so for printing
+$fn = 60;
+
+/* measured with calipers */
+ball_diameter = 11 + 0.75; // extra bit added for printing imprecision
+ball_radius = ball_diameter / 2;
+
+standoff_height = 60; // kyle eyeballed
+
+gap = 3;
+wall_thickness = 1;
+holder_floor = 3;
+holder_arms_length = 20;
+holder_height =
+ holder_floor + holder_arms_length + (11 / 16) * ball_diameter;
+
+holder_radius = ball_radius + wall_thickness;
+holder_diameter = holder_radius * 2;
+
+standoff_radius = holder_radius; // 0.580 / 2 inches from spec sheet
+standoff_lower_portion_height = standoff_height - holder_height;
+
+// eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
+caster_flange_height = 5;
+caster_flange_width = 20.32; // 0.800 inches
+
+deck_pitch = 25.4; // measured center to center on grid on pegboard
+deck_flange_height = 2.9464;
+deck_flange_screw_radius = 3.556 / 2; // For #6 machine screws
+deck_flange_radius = (deck_pitch) / 2 + deck_flange_screw_radius + 3;
+
+module deck_flange() {
+ deck_pitch_diagonal = sqrt(2 * pow(deck_pitch, 2));
+ difference() {
+ scale([0.35, 0.35, 1]) {
+ linear_extrude(height = deck_flange_height) {
+ oshw(); } }
+ for (ii = [-1, 1]) {
+ translate([deck_pitch_diagonal / 2 * ii, 0, -.1])
+ cylinder(h = deck_flange_height * 1.1,
+ r = deck_flange_screw_radius); }
+ translate([0, deck_pitch_diagonal / 2, -.1])
+ cylinder(h = deck_flange_height * 1.1,
+ r = deck_flange_screw_radius); } }
+
+module deck_flange_reinforcement() {
+ translate([-deck_flange_radius,
+ -.5 * deck_flange_height / 2,
+ deck_flange_height]) {
+ difference() {
+ cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]);
+ translate([-.1, -.05 * deck_flange_height, 0]) {
+ rotate([0, -45, 0]) {
+ cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
+ deck_flange_height * 1.1, // 1.1 is bigger than 1
+ deck_flange_radius]); } } } } }
+
+module ball_holder() {
+ difference() {
+ union() {
+ cylinder(r = holder_radius, h = holder_height);
+ translate([0, 0, holder_arms_length]) {
+ cylinder(r1 = holder_radius,
+ r2 = holder_radius + wall_thickness,
+ h = wall_thickness);
+ translate([0, 0, wall_thickness]) {
+ cylinder(r = wall_thickness + holder_radius,
+ h = holder_height
+ - holder_arms_length
+ - wall_thickness); } } }
+ translate([0, 0, ball_radius + holder_floor + holder_arms_length]) {
+ sphere(r = ball_radius); }
+ translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]) {
+ cube([holder_diameter + wall_thickness * 2 + 0.1,
+ gap,
+ holder_height - holder_floor + 0.1],
+ center = true); } } }
+
+module caster_standoff() {
+ cylinder(h = standoff_lower_portion_height,
+ r = standoff_radius);
+ deck_flange();
+ for (ii = [0:3]) {
+ rotate([0, 0, 45 + 90 * ii])
+ deck_flange_reinforcement(); }
+ translate([0, 0, standoff_lower_portion_height]) {
+ ball_holder(); } }