| 1 | // challenge-bot |
| 2 | // GNU AGPLv3 (or later at your option) |
| 3 | // project available at these locations: |
| 4 | // https://gitorious.org/ozzloy/challenge-bot |
| 5 | // https://github.com/waynegramlich/challenge-bot |
| 6 | |
| 7 | use <oshw.scad> |
| 8 | |
| 9 | // use 10 ish for development, 60 or so for printing |
| 10 | $fn = 60; |
| 11 | |
| 12 | /* measured with calipers */ |
| 13 | ball_diameter = 11 + 0.75; // extra bit added for printing imprecision |
| 14 | ball_radius = ball_diameter / 2; |
| 15 | |
| 16 | standoff_height = 60; // kyle eyeballed |
| 17 | |
| 18 | gap = 3; |
| 19 | wall_thickness = 1; |
| 20 | holder_floor = 3; |
| 21 | holder_arms_length = 20; |
| 22 | holder_height = |
| 23 | holder_floor + holder_arms_length + (11 / 16) * ball_diameter; |
| 24 | |
| 25 | holder_radius = ball_radius + wall_thickness; |
| 26 | holder_diameter = holder_radius * 2; |
| 27 | |
| 28 | standoff_radius = holder_radius; // 0.580 / 2 inches from spec sheet |
| 29 | standoff_lower_portion_height = standoff_height - holder_height; |
| 30 | |
| 31 | // eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger |
| 32 | caster_flange_height = 5; |
| 33 | caster_flange_width = 20.32; // 0.800 inches |
| 34 | |
| 35 | deck_pitch = 25.4; // measured center to center on grid on pegboard |
| 36 | deck_flange_height = 2.9464; |
| 37 | deck_flange_screw_radius = 3.556 / 2; // For #6 machine screws |
| 38 | deck_flange_radius = (deck_pitch) / 2 + deck_flange_screw_radius + 3; |
| 39 | |
| 40 | module deck_flange() { |
| 41 | deck_pitch_diagonal = sqrt(2 * pow(deck_pitch, 2)); |
| 42 | difference() { |
| 43 | scale([0.35, 0.35, 1]) { |
| 44 | linear_extrude(height = deck_flange_height) { |
| 45 | oshw(); } } |
| 46 | for (ii = [-1, 1]) { |
| 47 | translate([deck_pitch_diagonal / 2 * ii, 0, -.1]) |
| 48 | cylinder(h = deck_flange_height * 1.1, |
| 49 | r = deck_flange_screw_radius); } |
| 50 | translate([0, deck_pitch_diagonal / 2, -.1]) |
| 51 | cylinder(h = deck_flange_height * 1.1, |
| 52 | r = deck_flange_screw_radius); } } |
| 53 | |
| 54 | module deck_flange_reinforcement() { |
| 55 | translate([-deck_flange_radius, |
| 56 | -.5 * deck_flange_height / 2, |
| 57 | deck_flange_height]) { |
| 58 | difference() { |
| 59 | cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]); |
| 60 | translate([-.1, -.05 * deck_flange_height, 0]) { |
| 61 | rotate([0, -45, 0]) { |
| 62 | cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2) |
| 63 | deck_flange_height * 1.1, // 1.1 is bigger than 1 |
| 64 | deck_flange_radius]); } } } } } |
| 65 | |
| 66 | module ball_holder() { |
| 67 | difference() { |
| 68 | union() { |
| 69 | cylinder(r = holder_radius, h = holder_height); |
| 70 | translate([0, 0, holder_arms_length]) { |
| 71 | cylinder(r1 = holder_radius, |
| 72 | r2 = holder_radius + wall_thickness, |
| 73 | h = wall_thickness); |
| 74 | translate([0, 0, wall_thickness]) { |
| 75 | cylinder(r = wall_thickness + holder_radius, |
| 76 | h = holder_height |
| 77 | - holder_arms_length |
| 78 | - wall_thickness); } } } |
| 79 | translate([0, 0, ball_radius + holder_floor + holder_arms_length]) { |
| 80 | sphere(r = ball_radius); } |
| 81 | translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]) { |
| 82 | cube([holder_diameter + wall_thickness * 2 + 0.1, |
| 83 | gap, |
| 84 | holder_height - holder_floor + 0.1], |
| 85 | center = true); } } } |
| 86 | |
| 87 | module caster_standoff() { |
| 88 | cylinder(h = standoff_lower_portion_height, |
| 89 | r = standoff_radius); |
| 90 | deck_flange(); |
| 91 | for (ii = [0:3]) { |
| 92 | rotate([0, 0, 45 + 90 * ii]) |
| 93 | deck_flange_reinforcement(); } |
| 94 | translate([0, 0, standoff_lower_portion_height]) { |
| 95 | ball_holder(); } } |