cover more of the ball with ball holder

[challenge-bot] / 3d-printables / caster-standoff-data.scad

/*
  Copyright (C) 2015 Daniel Watson
  See the end of the file for license conditions.
*/
// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available here:
// https://challenge-bot.com/

use <oshw.scad>

// use 10 ish for development, 60 or so for printing
$fn = 100;

/* measured with calipers */
ball_diameter = 11 + 0.85; // extra bit added for printing imprecision
ball_radius = ball_diameter / 2;

standoff_height = 60; // kyle eyeballed

/*
  notes on printing:
  * slow down just before top solid infill of deck flange
  * slow down just before switching from solid to forked portion of standoff
 */

gap = 3;
wall_thickness = 1;
holder_floor = 3;
holder_arms_length = 20;
holder_height =
  holder_floor + holder_arms_length + (3 / 4) * ball_diameter;

holder_radius = ball_radius + wall_thickness;
holder_diameter = holder_radius * 2;

standoff_radius = holder_radius; // 0.580 / 2 inches from spec sheet
standoff_lower_portion_height = standoff_height - holder_height;

// eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
caster_flange_height = 5;
caster_flange_width = 20.32;  // 0.800 inches

deck_pitch = 25.4; // measured center to center on grid on pegboard
deck_flange_height = 2.9464;
deck_flange_screw_radius = 3.556 / 2 + 0.4;  // For #6 machine screws
deck_flange_radius = (deck_pitch) / 2 + deck_flange_screw_radius + 3;

module deck_flange() {
  deck_pitch_diagonal = sqrt(2 * pow(deck_pitch, 2));
  cylinder(h = deck_flange_height, r = holder_radius + 2);
  difference() {
    scale([0.40, 0.40, 1]) {
      linear_extrude(height = deck_flange_height) {
        oshw(); } }
    for (ii = [-1, 1]) {
      translate([deck_pitch_diagonal / 2 * ii, 0, -.1])
      cylinder(h = deck_flange_height * 1.1,
               r = deck_flange_screw_radius); }
    translate([0, deck_pitch_diagonal / 2, -.1])
    cylinder(h = deck_flange_height * 1.1,
             r = deck_flange_screw_radius); } }

module deck_flange_reinforcement() {
  translate([-deck_flange_radius,
             -.5 * deck_flange_height / 2,
             deck_flange_height]) {
    difference() {
      cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]);
      translate([-.1, -.05 * deck_flange_height, 0]) {
        rotate([0, -45, 0]) {
          cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
                deck_flange_height * 1.1, // 1.1 is bigger than 1
                deck_flange_radius]); } } } } }

module ball_holder() {
  difference() {
    union() {
      cylinder(r = holder_radius, h = holder_height);
      translate([0, 0, holder_arms_length]) {
        cylinder(r1 = holder_radius,
                 r2 = holder_radius + wall_thickness,
                 h = wall_thickness);
        translate([0, 0, wall_thickness]) {
          cylinder(r = wall_thickness + holder_radius,
                   h = holder_height
                       - holder_arms_length
                       - wall_thickness); } } }
    translate([0, 0, ball_radius + holder_floor + holder_arms_length]) {
      sphere(r = ball_radius); }
    translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]) {
      cube([holder_diameter + wall_thickness * 2 + 0.1,
            gap,
            holder_height - holder_floor + 0.1],
           center = true); } } }

module caster_standoff() {
  cylinder(h = standoff_lower_portion_height,
           r = standoff_radius);
  deck_flange();
  for (ii = [0:3]) {
    rotate([0, 0, 45 + 90 * ii])
    deck_flange_reinforcement(); }
  translate([0, 0, standoff_lower_portion_height]) {
    ball_holder(); } }

/*
  This file is part of challenge-bot.

  Challenge-bot is free software: you can redistribute it and/or modify
  it under the terms of the GNU Affero General Public License as published by
  the Free Software Foundation, either version 3 of the License, or
  (at your option) any later version.

  GNU Affero Emacs is distributed in the hope that it will be useful,
  but WITHOUT ANY WARRANTY; without even the implied warranty of
  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  GNU Affero General Public License for more details.

  You should have received a copy of the GNU Affero General Public License
  along with challenge-bot.  If not, see <http://www.gnu.org/licenses/>.
*/