add wire-jig for cutting wires the right lengths

[challenge-bot] / 3d-printables / wire-jig.scad

// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available at these locations:
// https://gitorious.org/ozzloy/challenge-bot
// https://github.com/waynegramlich/challenge-bot

$fn = 20;

wire_channel_width = 6;
wire_channel_height = 6;

wire_diameter_measured = 1.17;
wire_diameter_fudge = 0.5;
wire_diameter = wire_diameter_measured + wire_diameter_fudge;
wire_radius = wire_diameter / 2;

wire_lengths = [10, //strip wire this much
                35, //short breadboard wire
                63, //ground to ground
                120, //arduino breadboard wire
                180 //motor wire
               ];

module wire_channel_groove_2d(width, height, wire_radius) {
  difference() {
    square([width, height]);
    translate([width / 2, height]) {
      circle(r = wire_radius); } } }


module wire_channel_groove(width, height, wire_radius, length){
  rotate(a = 90, v = [1, 0, 0]){
    linear_extrude(height = length){
      wire_channel_groove_2d(width, height, wire_radius); } } }

for(ii = [0:len(wire_lengths) - 1]) {
  translate([wire_channel_width * ii, 0, 0]) {
    wire_channel_groove(wire_channel_width,
                        wire_channel_height,
                        wire_radius,
                        wire_lengths[ii]); } }