add cleaned up dobervich's mounting bracket drill jig

[challenge-bot] / caster-standoff.scad

// challenge-bot
// GNU AGPLv3 (or later at your option)
// project available at these locations:
// https://gitorious.org/ozzloy/challenge-bot
// https://github.com/waynegramlich/challenge-bot

standoff_radius = 14.732 / 2; // 0.580 / 2 inches from spec sheet
standoff_height = 55; // eyeballed

nut_short_side = 4.7; // from calipers
nut_height = 1.6; // from calipers

// eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
caster_flange_height = 2.9464 * 2;
caster_flange_width = 20.32;  // 0.800 inches
caster_flange_screw_radius = 2.286 / 2;  // 0.090 inches
caster_flange_screw_length = 8; // eyeballed

deck_grid_width = 25.4; // guessing
/* setting deck flange values same as caster flange pending
 * physical testing. */
deck_flange_height = 2.9464 * 2;
deck_flange_screw_radius = 2.286 / 2;  // 0.090 inches
deck_flange_radius = deck_grid_width * 1.5;

module deck_flange(){
  difference(){
    cylinder(h = deck_flange_height, r = deck_flange_radius);
    for(ii = [-1, 1]){
      translate([deck_grid_width * ii, 0, -.1])
        cylinder(h = deck_flange_height * 1.1,
                 r = deck_flange_screw_radius,
                 $fn = 20);}
    for(ii = [-1, 1]){
      translate([0, deck_grid_width * ii, -.1])
        cylinder(h = deck_flange_height * 1.1,
                 r = deck_flange_screw_radius,
                 $fn = 20);}}}

module deck_flange_reinforcement(){
  translate([-deck_flange_radius,
             -.5 * deck_flange_height,
             deck_flange_height]){
    difference (){
      cube([deck_flange_radius, deck_flange_height, deck_flange_radius]);
      translate([-.1, -.05 * deck_flange_height, 0]){
        rotate([0, -45, 0]){
          cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
                deck_flange_height * 1.1, // 1.1 is bigger than 1
                deck_flange_radius]);}}}}}

module caster_flange_screws(){
  translate([standoff_radius, 0, 0])
    cylinder(h = caster_flange_screw_length,
             r = caster_flange_screw_radius,
             $fn = 20);
  translate([-standoff_radius, 0, 0])
    cylinder(h = caster_flange_screw_length,
             r = caster_flange_screw_radius,
             $fn = 20);}

module caster_flange(){
  side_radius = caster_flange_width / 2 - standoff_radius;
  hull(){
    cylinder(h = caster_flange_height, r = standoff_radius);
    translate([standoff_radius, 0, 0])
      cylinder(h = caster_flange_height, r = side_radius);
    translate([-standoff_radius, 0, 0])
      cylinder(h = caster_flange_height, r = side_radius);}}

module nut(size, height){
    width = size/1.75;
    for (r = [-60, 0, 60]) rotate([0,0,r]) cube([width, size, height], true);}

module nuts(){
  translate([standoff_radius, 0, nut_height/2])
    nut(nut_short_side, nut_height);
  translate([-standoff_radius, 0, nut_height/2])
    nut(nut_short_side, nut_height);}

module caster_standoff(){
  difference(){
    union(){
      cylinder(h = standoff_height, r = standoff_radius);
      translate([0, 0, standoff_height - caster_flange_height])
        caster_flange();}
    translate([0, 0, standoff_height - caster_flange_screw_length * 1.1 + 0.1])
      scale([1, 1, 1.1])
        caster_flange_screws();
    translate([0, 0, standoff_height - (caster_flange_height + nut_height)])
      nuts();}
  deck_flange();
  for(ii = [0:3]){
    rotate([0, 0, 45 + 90 * ii])
      deck_flange_reinforcement();}}

caster_standoff();