challenge-bot.com Git - challenge-bot/blob - caster-standoff.scad

   1 // challenge-bot
   2 // GNU AGPLv3 (or later at your option)
   3 // project available at these locations:
   4 // https://gitorious.org/ozzloy/challenge-bot
   5 // https://github.com/waynegramlich/challenge-bot
   6
   7 standoff_radius = 14.732 / 2; // 0.580 / 2 inches from spec sheet
   8 standoff_height = 55; // eyeballed
   9
  10 nut_short_side = 4.7; // from calipers
  11 nut_height = 1.6; // from calipers
  12
  13 // eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
  14 caster_flange_height = 2.9464 * 2;
  15 caster_flange_width = 20.32;  // 0.800 inches
  16 caster_flange_screw_radius = 2.286 / 2;  // 0.090 inches
  17 caster_flange_screw_length = 8; // eyeballed
  18
  19 deck_grid_width = 25.4; // guessing
  20 /* setting deck flange values same as caster flange pending
  21  * physical testing. */
  22 deck_flange_height = 2.9464 * 2;
  23 deck_flange_screw_radius = 2.286 / 2;  // 0.090 inches
  24 deck_flange_radius = deck_grid_width * 1.5;
  25
  26 module deck_flange(){
  27   difference(){
  28     cylinder(h = deck_flange_height, r = deck_flange_radius);
  29     for(ii = [-1, 1]){
  30       translate([deck_grid_width * ii, 0, -.1])
  31         cylinder(h = deck_flange_height * 1.1,
  32                  r = deck_flange_screw_radius,
  33                  $fn = 20);}
  34     for(ii = [-1, 1]){
  35       translate([0, deck_grid_width * ii, -.1])
  36         cylinder(h = deck_flange_height * 1.1,
  37                  r = deck_flange_screw_radius,
  38                  $fn = 20);}}}
  39
  40 module deck_flange_reinforcement(){
  41   translate([-deck_flange_radius,
  42              -.5 * deck_flange_height,
  43              deck_flange_height]){
  44     difference (){
  45       cube([deck_flange_radius, deck_flange_height, deck_flange_radius]);
  46       translate([-.1, -.05 * deck_flange_height, 0]){
  47         rotate([0, -45, 0]){
  48           cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
  49                 deck_flange_height * 1.1, // 1.1 is bigger than 1
  50                 deck_flange_radius]);}}}}}
  51
  52 module caster_flange_screws(){
  53   translate([standoff_radius, 0, 0])
  54     cylinder(h = caster_flange_screw_length,
  55              r = caster_flange_screw_radius,
  56              $fn = 20);
  57   translate([-standoff_radius, 0, 0])
  58     cylinder(h = caster_flange_screw_length,
  59              r = caster_flange_screw_radius,
  60              $fn = 20);}
  61
  62 module caster_flange(){
  63   side_radius = caster_flange_width / 2 - standoff_radius;
  64   hull(){
  65     cylinder(h = caster_flange_height, r = standoff_radius);
  66     translate([standoff_radius, 0, 0])
  67       cylinder(h = caster_flange_height, r = side_radius);
  68     translate([-standoff_radius, 0, 0])
  69       cylinder(h = caster_flange_height, r = side_radius);}}
  70
  71 module nut(size, height){
  72     width = size/1.75;
  73     for (r = [-60, 0, 60]) rotate([0,0,r]) cube([width, size, height], true);}
  74
  75 module nuts(){
  76   translate([standoff_radius, 0, nut_height/2])
  77     nut(nut_short_side, nut_height);
  78   translate([-standoff_radius, 0, nut_height/2])
  79     nut(nut_short_side, nut_height);}
  80
  81 module caster_standoff(){
  82   difference(){
  83     union(){
  84       cylinder(h = standoff_height, r = standoff_radius);
  85       translate([0, 0, standoff_height - caster_flange_height])
  86         caster_flange();}
  87     translate([0, 0, standoff_height - caster_flange_screw_length * 1.1 + 0.1])
  88       scale([1, 1, 1.1])
  89         caster_flange_screws();
  90     translate([0, 0, standoff_height - (caster_flange_height + nut_height)])
  91       nuts();}
  92   deck_flange();
  93   for(ii = [0:3]){
  94     rotate([0, 0, 45 + 90 * ii])
  95       deck_flange_reinforcement();}}
  96
  97 caster_standoff();