challenge-bot.com Git - challenge-bot/blob - 3d-printables/caster-standoff-data.scad

   1 /*
   2   Copyright (C) 2015 Daniel Watson
   3   See the end of the file for license conditions.
   4 */
   5 // challenge-bot
   6 // GNU AGPLv3 (or later at your option)
   7 // project available here:
   8 // https://challenge-bot.com/
   9
  10 include <open-source-hardware-logo.scad>
  11
  12 // use 10 ish for development, 60 or so for printing
  13 $fn = 100;
  14
  15 /* measured with calipers */
  16 ball_diameter = 11 + 0.85; // extra bit added for printing imprecision
  17 ball_radius = ball_diameter / 2;
  18
  19 standoff_height = 60; // kyle eyeballed
  20
  21 /*
  22   notes on printing:
  23   * slow down just before top solid infill of deck flange
  24   * slow down just before switching from solid to forked portion of standoff
  25  */
  26
  27 gap = 3;
  28 wall_thickness = 1;
  29 holder_floor = 3;
  30 holder_arms_length = 20;
  31 holder_height =
  32   holder_floor + holder_arms_length + (3 / 4) * ball_diameter;
  33
  34 holder_radius = ball_radius + wall_thickness;
  35 holder_diameter = holder_radius * 2;
  36
  37 standoff_radius = holder_radius; // 0.580 / 2 inches from spec sheet
  38 standoff_lower_portion_height = standoff_height - holder_height;
  39
  40 // eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
  41 caster_flange_height = 5;
  42 caster_flange_width = 20.32;  // 0.800 inches
  43
  44 deck_pitch = 25.4; // measured center to center on grid on pegboard
  45 deck_flange_height = 2.9464;
  46 deck_flange_screw_radius = 3.556 / 2 + 0.4;  // For #6 machine screws
  47 deck_flange_radius = (deck_pitch) / 2 + deck_flange_screw_radius + 3;
  48
  49 module deck_flange() {
  50   deck_pitch_diagonal = sqrt(2 * pow(deck_pitch, 2));
  51   cylinder(h = deck_flange_height, r = holder_radius + 2);
  52   difference() {
  53     open_source_hardware_logo(26, deck_flange_height);
  54     for (ii = [-1, 1]) {
  55       translate([deck_pitch_diagonal / 2 * ii, 0, -.1])
  56       cylinder(h = deck_flange_height * 1.1,
  57                r = deck_flange_screw_radius); }
  58     translate([0, deck_pitch_diagonal / 2, -.1])
  59     cylinder(h = deck_flange_height * 1.1,
  60              r = deck_flange_screw_radius); } }
  61
  62 module deck_flange_reinforcement() {
  63   translate([-deck_flange_radius,
  64              -.5 * deck_flange_height / 2,
  65              deck_flange_height]) {
  66     difference() {
  67       cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]);
  68       translate([-.1, -.05 * deck_flange_height, 0]) {
  69         rotate([0, -45, 0]) {
  70           cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
  71                 deck_flange_height * 1.1, // 1.1 is bigger than 1
  72                 deck_flange_radius]); } } } } }
  73
  74 module ball_holder() {
  75   difference() {
  76     union() {
  77       cylinder(r = holder_radius, h = holder_height);
  78       translate([0, 0, holder_arms_length]) {
  79         cylinder(r1 = holder_radius,
  80                  r2 = holder_radius + wall_thickness,
  81                  h = wall_thickness);
  82         translate([0, 0, wall_thickness]) {
  83           cylinder(r = wall_thickness + holder_radius,
  84                    h = holder_height
  85                        - holder_arms_length
  86                        - wall_thickness); } } }
  87     translate([0, 0, ball_radius + holder_floor + holder_arms_length]) {
  88       sphere(r = ball_radius); }
  89     translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]) {
  90       cube([holder_diameter + wall_thickness * 2 + 0.1,
  91             gap,
  92             holder_height - holder_floor + 0.1],
  93            center = true); } } }
  94
  95 module caster_standoff() {
  96   cylinder(h = standoff_lower_portion_height,
  97            r = standoff_radius);
  98   deck_flange();
  99   for (ii = [0:3]) {
 100     rotate([0, 0, 45 + 90 * ii])
 101     deck_flange_reinforcement(); }
 102   translate([0, 0, standoff_lower_portion_height]) {
 103     ball_holder(); } }
 104
 105 /*
 106   This file is part of challenge-bot.
 107
 108   Challenge-bot is free software: you can redistribute it and/or modify
 109   it under the terms of the GNU Affero General Public License as published by
 110   the Free Software Foundation, either version 3 of the License, or
 111   (at your option) any later version.
 112
 113   GNU Affero Emacs is distributed in the hope that it will be useful,
 114   but WITHOUT ANY WARRANTY; without even the implied warranty of
 115   MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 116   GNU Affero General Public License for more details.
 117
 118   You should have received a copy of the GNU Affero General Public License
 119   along with challenge-bot.  If not, see <http://www.gnu.org/licenses/>.
 120 */