challenge-bot.com Git - challenge-bot/blob - 3d-printables/caster-standoff.scad

   1 // challenge-bot
   2 // GNU AGPLv3 (or later at your option)
   3 // project available at these locations:
   4 // https://gitorious.org/ozzloy/challenge-bot
   5 // https://github.com/waynegramlich/challenge-bot
   6
   7 include <caster-standoff-dimensions.scad>
   8 use <oshw.scad>
   9
  10 // use 10 ish for development, 60 or so for printing
  11 $fn = 60;
  12
  13 module deck_flange(){
  14   deck_pitch_diagonal = sqrt(2 * pow(deck_pitch, 2));
  15   difference(){
  16     scale([0.35, 0.35, 1]){
  17       linear_extrude(height = deck_flange_height){
  18         oshw();}}
  19     for(ii = [-1, 1]){
  20       translate([deck_pitch_diagonal / 2 * ii, 0, -.1])
  21         cylinder(h = deck_flange_height * 1.1,
  22                  r = deck_flange_screw_radius);}
  23     translate([0, deck_pitch_diagonal / 2, -.1])
  24       cylinder(h = deck_flange_height * 1.1,
  25                r = deck_flange_screw_radius);}}
  26
  27 module deck_flange_reinforcement(){
  28   translate([-deck_flange_radius,
  29              -.5 * deck_flange_height / 2,
  30              deck_flange_height]){
  31     difference (){
  32       cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]);
  33       translate([-.1, -.05 * deck_flange_height, 0]){
  34         rotate([0, -45, 0]){
  35           cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
  36                 deck_flange_height * 1.1, // 1.1 is bigger than 1
  37                 deck_flange_radius]);}}}}}
  38
  39 module ball_holder(){
  40   difference (){
  41     union(){
  42       cylinder(r = holder_radius, h = holder_height);
  43       translate([0, 0, holder_arms_length]){
  44         cylinder(r1 = holder_radius,
  45                  r2 = holder_radius + wall_thickness,
  46                  h = wall_thickness);
  47         translate([0, 0, wall_thickness]){
  48           cylinder(r = wall_thickness + holder_radius,
  49                    h = holder_height
  50                        - holder_arms_length
  51                        - wall_thickness); }}}
  52     translate([0, 0, ball_radius + holder_floor + holder_arms_length]){
  53       sphere(r = ball_radius);}
  54     translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]){
  55       cube([holder_diameter + wall_thickness * 2 + 0.1,
  56             gap,
  57             holder_height - holder_floor + 0.1],
  58            center = true);}}}
  59
  60 module caster_standoff(){
  61   cylinder(h = standoff_lower_portion_height,
  62            r = standoff_radius);
  63   deck_flange();
  64   for(ii = [0:3]){
  65     rotate([0, 0, 45 + 90 * ii])
  66       deck_flange_reinforcement();}
  67   translate([0, 0, standoff_lower_portion_height]){
  68     ball_holder();}}
  69
  70 caster_standoff();