challenge-bot.com Git - challenge-bot/blob - 3d-printables/caster-standoff.scad

   1 // challenge-bot
   2 // GNU AGPLv3 (or later at your option)
   3 // project available at these locations:
   4 // https://gitorious.org/ozzloy/challenge-bot
   5 // https://github.com/waynegramlich/challenge-bot
   6
   7 // use 10 ish for development, 60 or so for printing
   8 $fn = 60;
   9
  10 /* measured with calipers */
  11 ball_diameter = 12.7 + 0.80; // extra bit added for printing imprecision
  12 ball_radius = ball_diameter / 2;
  13
  14 wall_thickness = 1;
  15 holder_floor = 3;
  16 holder_arms_length = 10;
  17 holder_height =
  18   holder_floor + holder_arms_length + (11 / 16) * ball_diameter;
  19
  20 holder_radius = ball_radius + wall_thickness;
  21 holder_diameter = holder_radius * 2;
  22
  23 standoff_radius = holder_radius; // 0.580 / 2 inches from spec sheet
  24 standoff_height = 48 - holder_height; // eyeballed
  25
  26 // eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
  27 caster_flange_height = 5;
  28 caster_flange_width = 20.32;  // 0.800 inches
  29 caster_flange_screw_radius = 2.286 / 2;  // 0.090 inches
  30 caster_flange_screw_length = 8; // eyeballed
  31
  32 deck_grid_width = 25.4; // measured center to center on grid on pegboard
  33 deck_flange_height = 2.9464;
  34 deck_flange_screw_radius = 3.556 / 2;  // For #6 machine screws
  35 deck_flange_radius = (deck_grid_width) / 2 + deck_flange_screw_radius + 3;
  36
  37 module deck_flange(){
  38   difference(){
  39     cylinder(h = deck_flange_height, r = deck_flange_radius);
  40     for(ii = [-1, 1]){
  41       translate([deck_grid_width / 2 * ii, 0, -.1])
  42         cylinder(h = deck_flange_height * 1.1,
  43                  r = deck_flange_screw_radius);
  44       translate([0, deck_grid_width / 2 * ii, -.1])
  45         cylinder(h = deck_flange_height * 1.1,
  46         r = deck_flange_screw_radius);}}}
  47
  48 module deck_flange_reinforcement(){
  49   translate([-deck_flange_radius,
  50              -.5 * deck_flange_height / 2,
  51              deck_flange_height]){
  52     difference (){
  53       cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]);
  54       translate([-.1, -.05 * deck_flange_height, 0]){
  55         rotate([0, -45, 0]){
  56           cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
  57                 deck_flange_height * 1.1, // 1.1 is bigger than 1
  58                 deck_flange_radius]);}}}}}
  59
  60 module ball_holder(){
  61   gap = wall_thickness * 4;
  62   difference (){
  63     cylinder(r = holder_radius, h = holder_height);
  64     translate([0, 0, ball_radius + holder_floor + holder_arms_length]){
  65       sphere(r = ball_radius);}
  66     translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]){
  67       cube([holder_diameter + 0.1, gap, holder_height - holder_floor + 0.1],
  68            center = true);}}}
  69
  70 module caster_standoff(){
  71   cylinder(h = standoff_height,
  72            r = standoff_radius);
  73   deck_flange();
  74   for(ii = [0:3]){
  75     rotate([0, 0, 45 + 90 * ii])
  76       deck_flange_reinforcement();}
  77   translate([0, 0, standoff_height]){
  78     ball_holder();}}
  79
  80 caster_standoff();