challenge-bot.com Git - challenge-bot/blob - 3d-printables/caster-standoff.scad

   1 // challenge-bot
   2 // GNU AGPLv3 (or later at your option)
   3 // project available at these locations:
   4 // https://gitorious.org/ozzloy/challenge-bot
   5 // https://github.com/waynegramlich/challenge-bot
   6
   7 use <oshw.scad>
   8
   9 // use 10 ish for development, 60 or so for printing
  10 $fn = 60;
  11
  12 /* measured with calipers */
  13 ball_diameter = 12.7 + 0.80; // extra bit added for printing imprecision
  14 ball_radius = ball_diameter / 2;
  15
  16 standoff_height = 60; // kyle eyeballed
  17
  18 wall_thickness = 1;
  19 holder_floor = 3;
  20 holder_arms_length = 20;
  21 holder_height =
  22   holder_floor + holder_arms_length + (11 / 16) * ball_diameter;
  23
  24 holder_radius = ball_radius + wall_thickness;
  25 holder_diameter = holder_radius * 2;
  26
  27 standoff_radius = holder_radius; // 0.580 / 2 inches from spec sheet
  28 standoff_lower_portion_height = standoff_height - holder_height;
  29
  30 // eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
  31 caster_flange_height = 5;
  32 caster_flange_width = 20.32;  // 0.800 inches
  33 caster_flange_screw_radius = 2.286 / 2;  // 0.090 inches
  34 caster_flange_screw_length = 8; // eyeballed
  35
  36 deck_pitch = 25.4; // measured center to center on grid on pegboard
  37 deck_flange_height = 2.9464;
  38 deck_flange_screw_radius = 3.556 / 2;  // For #6 machine screws
  39 deck_flange_radius = (deck_pitch) / 2 + deck_flange_screw_radius + 3;
  40
  41 module deck_flange(){
  42   deck_pitch_diagonal = sqrt(2 * pow(deck_pitch, 2));
  43   difference(){
  44     scale([0.35, 0.35, 1]){
  45       linear_extrude(height = deck_flange_height){
  46         oshw();}}
  47     for(ii = [-1, 1]){
  48       translate([deck_pitch_diagonal / 2 * ii, 0, -.1])
  49         cylinder(h = deck_flange_height * 1.1,
  50                  r = deck_flange_screw_radius);}
  51     translate([0, deck_pitch_diagonal / 2, -.1])
  52       cylinder(h = deck_flange_height * 1.1,
  53                r = deck_flange_screw_radius);}}
  54
  55 module deck_flange_reinforcement(){
  56   translate([-deck_flange_radius,
  57              -.5 * deck_flange_height / 2,
  58              deck_flange_height]){
  59     difference (){
  60       cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]);
  61       translate([-.1, -.05 * deck_flange_height, 0]){
  62         rotate([0, -45, 0]){
  63           cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
  64                 deck_flange_height * 1.1, // 1.1 is bigger than 1
  65                 deck_flange_radius]);}}}}}
  66
  67 module ball_holder(){
  68   gap = wall_thickness * 4;
  69   difference (){
  70     cylinder(r = holder_radius, h = holder_height);
  71     translate([0, 0, ball_radius + holder_floor + holder_arms_length]){
  72       sphere(r = ball_radius);}
  73     translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]){
  74       cube([holder_diameter + 0.1, gap, holder_height - holder_floor + 0.1],
  75            center = true);}}}
  76
  77 module caster_standoff(){
  78   cylinder(h = standoff_lower_portion_height,
  79            r = standoff_radius);
  80   deck_flange();
  81   for(ii = [0:3]){
  82     rotate([0, 0, 45 + 90 * ii])
  83       deck_flange_reinforcement();}
  84   translate([0, 0, standoff_lower_portion_height]){
  85     ball_holder();}}
  86
  87 caster_standoff();