challenge-bot.com Git - challenge-bot/blob - 3d-printables/caster-standoff.scad

   1 // challenge-bot
   2 // GNU AGPLv3 (or later at your option)
   3 // project available at these locations:
   4 // https://gitorious.org/ozzloy/challenge-bot
   5 // https://github.com/waynegramlich/challenge-bot
   6
   7 // use 10 ish for development, 60 or so for printing
   8 $fn = 60;
   9
  10 /* measured with calipers */
  11 ball_diameter = 12.7 + 0.80; // extra bit added for printing imprecision
  12 ball_radius = ball_diameter / 2;
  13
  14 standoff_height = 65; // kyle eyeballed
  15
  16 wall_thickness = 1;
  17 holder_floor = 3;
  18 holder_arms_length = 10;
  19 holder_height =
  20   holder_floor + holder_arms_length + (11 / 16) * ball_diameter;
  21
  22 holder_radius = ball_radius + wall_thickness;
  23 holder_diameter = holder_radius * 2;
  24
  25 standoff_radius = holder_radius; // 0.580 / 2 inches from spec sheet
  26 standoff_lower_portion_height = standoff_height - holder_height;
  27
  28 // eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
  29 caster_flange_height = 5;
  30 caster_flange_width = 20.32;  // 0.800 inches
  31 caster_flange_screw_radius = 2.286 / 2;  // 0.090 inches
  32 caster_flange_screw_length = 8; // eyeballed
  33
  34 deck_grid_width = 25.4; // measured center to center on grid on pegboard
  35 deck_flange_height = 2.9464;
  36 deck_flange_screw_radius = 3.556 / 2;  // For #6 machine screws
  37 deck_flange_radius = (deck_grid_width) / 2 + deck_flange_screw_radius + 3;
  38
  39 module deck_flange(){
  40   difference(){
  41     cylinder(h = deck_flange_height, r = deck_flange_radius);
  42     for(ii = [-1, 1]){
  43       translate([deck_grid_width / 2 * ii, 0, -.1])
  44         cylinder(h = deck_flange_height * 1.1,
  45                  r = deck_flange_screw_radius);
  46       translate([0, deck_grid_width / 2 * ii, -.1])
  47         cylinder(h = deck_flange_height * 1.1,
  48         r = deck_flange_screw_radius);}}}
  49
  50 module deck_flange_reinforcement(){
  51   translate([-deck_flange_radius,
  52              -.5 * deck_flange_height / 2,
  53              deck_flange_height]){
  54     difference (){
  55       cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]);
  56       translate([-.1, -.05 * deck_flange_height, 0]){
  57         rotate([0, -45, 0]){
  58           cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
  59                 deck_flange_height * 1.1, // 1.1 is bigger than 1
  60                 deck_flange_radius]);}}}}}
  61
  62 module ball_holder(){
  63   gap = wall_thickness * 4;
  64   difference (){
  65     cylinder(r = holder_radius, h = holder_height);
  66     translate([0, 0, ball_radius + holder_floor + holder_arms_length]){
  67       sphere(r = ball_radius);}
  68     translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]){
  69       cube([holder_diameter + 0.1, gap, holder_height - holder_floor + 0.1],
  70            center = true);}}}
  71
  72 module caster_standoff(){
  73   cylinder(h = standoff_lower_portion_height,
  74            r = standoff_radius);
  75   deck_flange();
  76   for(ii = [0:3]){
  77     rotate([0, 0, 45 + 90 * ii])
  78       deck_flange_reinforcement();}
  79   translate([0, 0, standoff_lower_portion_height]){
  80     ball_holder();}}
  81
  82 caster_standoff();