challenge-bot.com Git - challenge-bot/blob - 3d-printables/caster-standoff.scad

   1 // challenge-bot
   2 // GNU AGPLv3 (or later at your option)
   3 // project available at these locations:
   4 // https://gitorious.org/ozzloy/challenge-bot
   5 // https://github.com/waynegramlich/challenge-bot
   6
   7 use <oshw.scad>
   8
   9 // use 10 ish for development, 60 or so for printing
  10 $fn = 60;
  11
  12 /* measured with calipers */
  13 ball_diameter = 11 + 0.75; // extra bit added for printing imprecision
  14 ball_radius = ball_diameter / 2;
  15
  16 standoff_height = 60; // kyle eyeballed
  17
  18 gap = 3;
  19 wall_thickness = 1;
  20 holder_floor = 3;
  21 holder_arms_length = 20;
  22 holder_height =
  23   holder_floor + holder_arms_length + (11 / 16) * ball_diameter;
  24
  25 holder_radius = ball_radius + wall_thickness;
  26 holder_diameter = holder_radius * 2;
  27
  28 standoff_radius = holder_radius; // 0.580 / 2 inches from spec sheet
  29 standoff_lower_portion_height = standoff_height - holder_height;
  30
  31 // eyeballed caster flange height, (0.580/5) inches, times 2 to be stronger
  32 caster_flange_height = 5;
  33 caster_flange_width = 20.32;  // 0.800 inches
  34 caster_flange_screw_radius = 2.286 / 2;  // 0.090 inches
  35 caster_flange_screw_length = 8; // eyeballed
  36
  37 deck_pitch = 25.4; // measured center to center on grid on pegboard
  38 deck_flange_height = 2.9464;
  39 deck_flange_screw_radius = 3.556 / 2;  // For #6 machine screws
  40 deck_flange_radius = (deck_pitch) / 2 + deck_flange_screw_radius + 3;
  41
  42 module deck_flange(){
  43   deck_pitch_diagonal = sqrt(2 * pow(deck_pitch, 2));
  44   difference(){
  45     scale([0.35, 0.35, 1]){
  46       linear_extrude(height = deck_flange_height){
  47         oshw();}}
  48     for(ii = [-1, 1]){
  49       translate([deck_pitch_diagonal / 2 * ii, 0, -.1])
  50         cylinder(h = deck_flange_height * 1.1,
  51                  r = deck_flange_screw_radius);}
  52     translate([0, deck_pitch_diagonal / 2, -.1])
  53       cylinder(h = deck_flange_height * 1.1,
  54                r = deck_flange_screw_radius);}}
  55
  56 module deck_flange_reinforcement(){
  57   translate([-deck_flange_radius,
  58              -.5 * deck_flange_height / 2,
  59              deck_flange_height]){
  60     difference (){
  61       cube([deck_flange_radius, deck_flange_height / 2, deck_flange_radius]);
  62       translate([-.1, -.05 * deck_flange_height, 0]){
  63         rotate([0, -45, 0]){
  64           cube([deck_flange_radius * 1.5, // 1.5 is bigger than sqrt(2)
  65                 deck_flange_height * 1.1, // 1.1 is bigger than 1
  66                 deck_flange_radius]);}}}}}
  67
  68 module ball_holder(){
  69   difference (){
  70     union(){
  71       cylinder(r = holder_radius, h = holder_height);
  72       translate([0, 0, holder_arms_length]){
  73         cylinder(r1 = holder_radius,
  74                  r2 = holder_radius + wall_thickness,
  75                  h = wall_thickness);
  76         translate([0, 0, wall_thickness]){
  77           cylinder(r = wall_thickness + holder_radius,
  78                    h = holder_height
  79                        - holder_arms_length
  80                        - wall_thickness); }}}
  81     translate([0, 0, ball_radius + holder_floor + holder_arms_length]){
  82       sphere(r = ball_radius);}
  83     translate([0, 0, holder_floor + (holder_height - holder_floor) / 2 + 0.5]){
  84       cube([holder_diameter + wall_thickness * 2 + 0.1,
  85             gap,
  86             holder_height - holder_floor + 0.1],
  87            center = true);}}}
  88
  89 module caster_standoff(){
  90   cylinder(h = standoff_lower_portion_height,
  91            r = standoff_radius);
  92   deck_flange();
  93   for(ii = [0:3]){
  94     rotate([0, 0, 45 + 90 * ii])
  95       deck_flange_reinforcement();}
  96   translate([0, 0, standoff_lower_portion_height]){
  97     ball_holder();}}
  98
  99 caster_standoff();