challenge-bot.com Git - challenge-bot/blob - 3d-printables/motor-mount.scad

   1 // challenge-bot
   2 // GNU AGPLv3 (or later at your option)
   3 // project available at these locations:
   4 // https://gitorious.org/ozzloy/challenge-bot
   5 // https://github.com/waynegramlich/challenge-bot
   6
   7 $fn = 60;
   8
   9 // from schematic http://goo.gl/96RKol
  10 collar_radius = 9.2 / 2 + 0.25;
  11 nubbin_radius = 4.48 / 2;
  12 screw_radius = 2.9 / 2 + 0.35; // a little bigger so screws fit through
  13
  14 motor_height = 22.23;
  15
  16 // http://freespace.virgin.net/matt.waite/resource/handy/screwsize.htm
  17 _6_radius = 3.5 / 2 + 0.25;
  18
  19 // measurements we made up:
  20 mount_total_x = 38;
  21 mount_total_y = mount_total_x;
  22 mount_total_z = 3.175; // 3/16 in mm
  23
  24 module motor_holes(){
  25   collar_x_offset = 10.8;
  26   nubbin_x_offset = 22.23;
  27   // actual motor screw holes are 0.2 further than spec says
  28   screw_x_offset = 30.81 + 0.2;
  29   screw_y_offset = 17.44 / 2;
  30
  31   translate([collar_x_offset, 0, 0]){
  32     cylinder(r = collar_radius, h = mount_total_z + 0.1);}
  33   translate([nubbin_x_offset, 0, 0]){
  34     cylinder(r = nubbin_radius, h = mount_total_z + 0.1);}
  35   translate([screw_x_offset, 0, 0]){
  36     translate([0, screw_y_offset, 0]){
  37       cylinder(r = screw_radius, h = mount_total_z + 0.1);}
  38     translate([0, -screw_y_offset, 0]){
  39       cylinder(r = screw_radius, h = mount_total_z + 0.1);}}}
  40
  41 module bracket_holes(){
  42   translate([6.2, 0, 0])
  43     cylinder(r = _6_radius, h = mount_total_z + 0.1);
  44   translate([mount_total_x - 6.2, 0, 0])
  45     cylinder(r = _6_radius, h = mount_total_z + 0.1);}
  46
  47 module motor_mount(){
  48   difference(){
  49     cube([mount_total_x, mount_total_y, mount_total_z]);
  50     translate([0, 6.2, -0.05]){
  51       bracket_holes();}
  52     translate([1, mount_total_y - motor_height / 2 - 3, -0.05]){
  53       motor_holes();}}}
  54
  55 motor_mount();