challenge-bot.com Git - challenge-bot/blob - build-stages/g_follow/g_follow.ino

   1 /*
   2  This program is free software: you can redistribute it and/or modify
   3     it under the terms of the GNU Affero General Public License as
   4     published by the Free Software Foundation, either version 3 of the
   5     License, or (at your option) any later version.
   6
   7     This program is distributed in the hope that it will be useful,
   8     but WITHOUT ANY WARRANTY; without even the implied warranty of
   9     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  10     GNU Affero General Public License for more details.
  11
  12     You should have received a copy of the GNU Affero General Public License
  13     along with this program.  If not, see <http://www.gnu.org/licenses/>.
  14  */
  15
  16 // define which pins are connected to which components
  17 // blue wire
  18 int right_motor_forward_pin = 3;
  19 // orange wire
  20 int right_motor_backward_pin = 4;
  21 // white wire
  22 int right_motor_speed_pin = 5;
  23
  24 // yellow wire
  25 int right_echo_pin = 6;
  26 // blue wire
  27 int right_trigger_pin = 7;
  28
  29
  30 // blue wire
  31 int left_motor_forward_pin = 8;
  32 // orange wire
  33 int left_motor_backward_pin = 9;
  34 // white wire
  35 int left_motor_speed_pin = 10;
  36
  37 // yellow wire
  38 int left_echo_pin = 11;
  39 // blue wire
  40 int left_trigger_pin = 12;
  41
  42 void on(int pin){
  43   digitalWrite(pin, HIGH);}
  44
  45 void off(int pin){
  46   digitalWrite(pin, LOW);}
  47
  48 void set_motor(int speed_pin,
  49                int forward_pin,
  50                int backward_pin,
  51                int speed){
  52   if(speed > 0){
  53     off(backward_pin);
  54     on(forward_pin);}
  55   else if(speed < 0){
  56     off(forward_pin);
  57     on(backward_pin);
  58     speed = -speed;}
  59   else{ // speed is 0
  60     off(forward_pin);
  61     off(backward_pin);}
  62   // since speed has been set positive, no need to check if speed < -255.
  63   if(speed > 255){
  64     speed = 255;}
  65   analogWrite(speed_pin, speed);}
  66
  67 void go(int left_motor_speed, int right_motor_speed){
  68   set_motor(left_motor_speed_pin,
  69             left_motor_forward_pin,
  70             left_motor_backward_pin,
  71             left_motor_speed);
  72   set_motor(right_motor_speed_pin,
  73             right_motor_forward_pin,
  74             right_motor_backward_pin,
  75             right_motor_speed);}
  76
  77 int ping(int trigger, int echo){
  78   int ping_time = 0;
  79   // turn off trigger
  80   off(trigger);
  81   delayMicroseconds(2);
  82   // turn on the trigger and leave it on long enough for the
  83   // sonar sensor to notice
  84   on(trigger);
  85   delayMicroseconds(10);
  86   off(trigger);
  87   ping_time = pulseIn(echo, HIGH);
  88   if(ping_time <= 0){
  89     ping_time = 3000;}
  90   // sonar needs some time to recover before pinging again,
  91   // so make sure it gets enough sleep right here.  50 milliseconds
  92   delay(50);
  93   return ping_time;}
  94
  95 void setup(){
  96   Serial.begin(9600);
  97
  98   pinMode(right_motor_speed_pin, OUTPUT);
  99   pinMode(right_motor_forward_pin, OUTPUT);
 100   pinMode(right_motor_backward_pin, OUTPUT);
 101
 102   pinMode(right_echo_pin, INPUT);
 103   pinMode(right_trigger_pin, OUTPUT);
 104
 105   pinMode(left_motor_speed_pin, OUTPUT);
 106   pinMode(left_motor_forward_pin, OUTPUT);
 107   pinMode(left_motor_backward_pin, OUTPUT);
 108
 109   pinMode(left_echo_pin, INPUT);
 110   pinMode(left_trigger_pin, OUTPUT);
 111
 112   off(left_motor_speed_pin);
 113   off(left_motor_forward_pin);
 114   off(left_motor_backward_pin);
 115   off(left_trigger_pin);
 116
 117   off(right_motor_speed_pin);
 118   off(right_motor_forward_pin);
 119   off(right_motor_backward_pin);
 120   off(right_trigger_pin); }
 121
 122 void loop() {
 123   int left_speed;
 124   int right_speed;
 125
 126   // you'll need to adjust these based on your sonar sensor's behavior
 127   int desired_right_ping_time = 800;
 128   int desired_left_ping_time = 800;
 129
 130   unsigned int actual_left_ping_time = ping(left_trigger_pin, left_echo_pin);
 131   unsigned int actual_right_ping_time = ping(right_trigger_pin, right_echo_pin);
 132
 133   left_speed = actual_left_ping_time - desired_left_ping_time;
 134   right_speed = actual_right_ping_time - desired_right_ping_time;
 135
 136   Serial.print("left: ping = ");
 137   Serial.print(actual_left_ping_time);
 138   Serial.print(" speed = ");
 139   Serial.print(left_speed);
 140   Serial.print(" right: ping = ");
 141   Serial.print(actual_right_ping_time);
 142   Serial.print(" speed = ");
 143   Serial.print(right_speed);
 144   Serial.println();
 145
 146   go(left_speed, right_speed); }